Ich wollte mal ein paar Ideen zur Drehzahlmesser Reparatur der MP und SF Modelle in die Runde werfen.
mittlerweile spinnt ja jeder 3. Drehzahlmesser herum.
Die Hauptprobleme sind gelockerte Befestigungsschrauben, Ab vibrierte Bauteile auf der Platine und ausgeschlagene/verschlissene Drehspulinstrumente.
Hier gibt es gute technische Hintergrundinformationen über die Funktionsweise:
motorrad mz sm 125 Drehzahlmesser (cvieth.bplaced.net)
Mal im ersten Schritt das öffnen:
Hier noch der Schaltplan für den Signalgenerator.
Das OLED Display ist nicht zwingend notwendig, man kann auch einen Laptop mit Arduinosoftware und dem Seriellen Monitor als Display benutzen.
Hier der Arduino Code für den Signalgenerator, es muss die "U8glib" Bibliothek instaliiert werden
#include "U8glib.h"
#include <Wire.h>
int sensorPin = A0;
int LED_PIN = 13;
int sensorValue = 0;
U8GLIB_SH1106_128X64 u8g(U8G_I2C_OPT_NONE); // I2C / TWI
int xmax=128; // max length x-axis
int ymax=62; // max length y-axis
int xcenter=xmax/2; // center of x-axis
int ycenter=ymax/2+10; // center of y-axis
int arc=ymax/2;
int angle=0;
char* label[] = {"x1000"}; // some custom gauge labels
int labelXpos[] = {53, 45, 49, 53}; // predefined x-position of a gauge label
#define potmeterPin A1 // simulate analogue value with potentiometer
int p, w, m,a=10;
u8g_uint_t xx=0;
// ------------------------------------------------- void gauge() ------------------------------------------
void gauge(uint8_t angle) {
// draw border of the gauge
u8g.drawCircle(xcenter,ycenter,arc+6, U8G_DRAW_UPPER_RIGHT);
u8g.drawCircle(xcenter,ycenter,arc+4, U8G_DRAW_UPPER_RIGHT);
u8g.drawCircle(xcenter,ycenter,arc+6, U8G_DRAW_UPPER_LEFT);
u8g.drawCircle(xcenter,ycenter,arc+4, U8G_DRAW_UPPER_LEFT);
// draw the needle
float x1=sin(2*angle*2*3.14/360); // needle position
float y1=cos(2*angle*2*3.14/360);
u8g.drawLine(xcenter, ycenter, xcenter+arc*x1, ycenter-arc*y1);
u8g.drawDisc(xcenter, ycenter, 5, U8G_DRAW_UPPER_LEFT);
u8g.drawDisc(xcenter, ycenter, 5, U8G_DRAW_UPPER_RIGHT);
u8g.setFont(u8g_font_chikita);
// show scale labels
u8g.drawStr( 20, 42, "0");
u8g.drawStr( 22, 29, "2");
u8g.drawStr( 27, 18, "4");
u8g.drawStr( 39, 7, "6");
u8g.drawStr( 62, 14, "8");
u8g.drawStr( 83, 7, "10");
u8g.drawStr( 95, 18, "12");
u8g.drawStr( 101, 29, "14");
u8g.drawStr( 105, 42, "16");
// show gauge label
u8g.setPrintPos(labelXpos[0],32);
u8g.print(label[0]);
// show digital value and align its position
u8g.setFont(u8g_font_profont22);
u8g.setPrintPos(54,60);
if (w<10){ // leading 0 when value less than 10
u8g.print("0");
}
if (w>99) { // position at 100%
u8g.setPrintPos(47,60);
}
u8g.print(w);
}
// ------------------------------------------------- void setup() ------------------------------------------
void setup(void) {
Serial.begin(9600);
pinMode(LED_PIN, OUTPUT);
u8g.setFont(u8g_font_chikita);
u8g.setColorIndex(1); // Instructs the display to draw with a pixel on.
// assign default color value
if ( u8g.getMode() == U8G_MODE_R3G3B2 ) {
u8g.setColorIndex(255); // white
}
else if ( u8g.getMode() == U8G_MODE_GRAY2BIT ) {
u8g.setColorIndex(3); // max intensity
}
else if ( u8g.getMode() == U8G_MODE_BW ) {
u8g.setColorIndex(1); // pixel on
}
else if ( u8g.getMode() == U8G_MODE_HICOLOR ) {
u8g.setHiColorByRGB(255,255,255);
}
}
// ------------------------------------------------- void loop() ------------------------------------------
void loop(void) {
float t = map (analogRead (sensorPin), 0, 1023, 37, 220);
tone (LED_PIN, t);
p = (t * 60) ;
w = p ; // map it between 0 and 100
m = map(p, 0 , 16000, 0, 90); // map needle movement
Serial.print("rpm.val=");
Serial.println(p);
// show needle and dial
xx = m; // 135 = zero position, 180 = just before middle, 0 = middle, 45 = max
if (xx<45){ // positie correctie
xx=xx+135;
}
else {
xx=xx-45;
}
// picture loop
{
u8g.firstPage();
do {
gauge(xx);
}
while( u8g.nextPage() );
}
}Es folgt die Umbauanleitung auf einen Stepper Motor zur genaueren anzeige, denn der originale Drehzahlmesser ist ein totales Schätzeisen.
Respekt und vielen Dank!
Ich schätze ´mal, es gibt zwei bis drei Menschen hier, die das verstehen. Ich gehöre nicht dazu.
Bei einer Studienarbeit hatte ich einen kleinen Schrittmotor Sonceboz 6405R475 auf einer Platine montiert und über einen Atmel-µC angesteuert. Den konnte man direkt über die Pins vom µC betreiben, indem man die Stromrichtung durch beiden Spulen mit Low/High oder High/Low immer passend festgelegt hat. Das kleine Ding hat eine Masse bewegt, die bestimmt das 100-fache Trägheitsmoment eines einfachen Zeigers hatte, da war denn die Kunst, passende Beschleunigungs- und Bremsrampen umzusetzen.
Den Code für die Ansteuerung habe ich noch irgendwo, der kann aber "nur" eine Positionierung auf Ziel, vielleicht ist das für den Drehzahlmesser noch zu wenig. Es gab eine Funktion zum Setzen der Ausgänge mit voll- oder halbschritten und dann mussten letztendlich nur die Zeiten berechnet werden, die zwischen jedem Schritt eingehalten werden müssen, um das Geschwindigkeitsprofil zu fahren
Coole Sache! Bei der Gelegenheit könnte man noch einen Neopixel-RGB-Led-Ring hinter die Skala einbauen, das würd flashen 
Ich hab damals CCFL Ringe reingemacht, passen perfekt vom Durchmesser und man hat eine gleichmäßige Ausleuchtung.
Der schwarze Gehäusering bedarf nach dem Öffnen eine gute Nacharbeit, da sonst die Kante nicht mehr schön anzusehen ist. Beim Drehzahlmesser fällt es aber nicht so sehr auf, da später ja noch der Schaumstoff drumherum ist.
Die Nadel am besten über den Anschlag bringen und "auspendeln" lassen, später wieder genau so aufsetzen, dann muss man auch nichts justieren.
Die Scheiben sehen so aus
Als Steppermotor nehme ich einen Chinesichen Switec x.27 589 Clone
: Auto X27.589 X27-589 Gauge Speedometer Tachometer Stepper Motor Mustang Mazda3 | eBay
Der wird auch direkt vom Microcontroller gespeist. Laut Datenblatt von Atmel sind die Ausgänge dafür vorbereitet:
Hier der Schaltplan:
So wird der Stepper am Arduino verdrahtet:
und dann einfach mit Heißkleber auf die Tachoscheibe geklebt, der Anschlag auf der Tachoscheibe für die Zeigernadel muss entfernt werden
Ich gehe nochmal ins Detail beim Stepper umbau.
wenn man die original Platine wiederverwendet, was sinn ergibt, da der Drehzahlmesser dann 1:1 kompatibel zum Moped bleibt, kann man sich ein paar dinge sparen wie den 1Ohm/5Watt Vorwiderstand, die Eingangsdiode D1 und die Diode D3
Ohne Platine fliegend verdrahtet
Rückseite
Nachdem der Stepper auf die Tachoscheibe geklebt wurde, muss das Loch in der Zeigernadel auf 1mm aufgebohrt werden
Jetzt wird der 8000 rpm Code auf den Arduino geladen. Der Zeiger wandert dann immer auf 8.000 rpm, er sollte so aufgesteckt werden das 8.000 rpm exakt angezeigt werden.
/* ///Drehzahlmesser_Micros-SWITEC///
// |**********************************************************************;
* Project : Digitaler Drehzahlmesser mit analoger Anzeige über Switec X.25 / X.27 Steppermotor für die
* Aprilia RS 125 MP + SF
*
* Program name : Drehzahlmesser_Micros-SWITEC.ino
*
* Author : InterlinkKnight
*
* Date created : 05/23/2019
*
* Modified by : el bodo es loco
*
* Revision History :
*
* Date modifiied Vers. Revision Date
* 06/08/2020 2.0 06/11/2020
*
|**********************************************************************;
*/
#include <Wire.h>
#include <SwitecX25.h>
#define STEPS (315*3)
#define LED_PIN 13 //
SwitecX25 motor1(STEPS,6,7,11,10);
//##### Kalibrierung #####//
//########################// Wichtige Parameter sind mit "####" gekennzeichnet
//Einstellung Drehzahlabnahme//
const byte PulsesPerRevolution = 1; // #### 1 für Drehzahlmessung am Pickup oder Zündspule; 6 für Drehzahlmessung an der Lima (ROTAX 122 und 123)
// bei der Mito ist der Wert an der Lichtmaschine und der Zündspule 2, es muss ggf. bei anderen Fahrzeugen die Drehzahl am Drehzahlmesser der Fahrzeugs
// und die Drehzahl auf der Skala verglichen werden und der PPR Wert von 1-6 angepasst werden bis die Drehzahlen übereinstimmen
//Timeout und Genauigkeit//
const unsigned long ZeroTimeout = 100000;
const byte numReadings = 1; //Anzahl der Messwertblöcke zur Mittelwert bildung Je höher des to genauer aber auch träger, für eine flüssige Nadelbewegung muss der Wert 1 sein
/////////////
// Variablen:
/////////////
volatile unsigned long LastTimeWeMeasured;
volatile unsigned long PeriodBetweenPulses = ZeroTimeout+1000;
volatile unsigned long PeriodAverage = ZeroTimeout+1000;
unsigned long FrequencyRaw;
unsigned long FrequencyReal;
unsigned long RPM;
unsigned int PulseCounter = 1;
unsigned long PeriodSum;
unsigned long LastTimeCycleMeasure = LastTimeWeMeasured;
unsigned long CurrentMicros = micros();
unsigned int AmountOfReadings = 1;
unsigned int ZeroDebouncingExtra;
unsigned long readings[numReadings];
unsigned long readIndex;
unsigned long total;
unsigned long average;
void setup()
{
Serial.begin(9600);
Wire.begin();
attachInterrupt(digitalPinToInterrupt(3), Pulse_Event, RISING);
pinMode (3, INPUT_PULLUP);
static int nextPos = 0;
motor1.zero();// run the motor against the stops
delay(200);
motor1.zero();
motor1.setPosition(STEPS/2); //STEPS/2
delay(100);
}
int pos=0; //Position in steps(0-630)= (0°-315°)
void loop()
{
LastTimeCycleMeasure = LastTimeWeMeasured;
CurrentMicros = micros();
if(CurrentMicros < LastTimeCycleMeasure)
{
LastTimeCycleMeasure = CurrentMicros;
}
FrequencyRaw = 10000000000 / PeriodAverage;
if(PeriodBetweenPulses > ZeroTimeout - ZeroDebouncingExtra || CurrentMicros - LastTimeCycleMeasure > ZeroTimeout - ZeroDebouncingExtra)
{
FrequencyRaw = 0;
ZeroDebouncingExtra = 2000;
}
else
{
ZeroDebouncingExtra = 0;
}
FrequencyReal = FrequencyRaw / 10000;
RPM = FrequencyRaw / PulsesPerRevolution * 60;
RPM = RPM / 10000;
total = total - readings[readIndex];
readings[readIndex] = RPM;
total = total + readings[readIndex];
readIndex = readIndex + 1;
if (readIndex >= numReadings)
{
readIndex = 0;
}
average = total / numReadings;
int r = 8000; //RPM ; // set to 8000 to calibrate the needle
int set = map(r,1000,14000,112,810);
if (RPM <= 14000){ // aggle limit to max. 14.000 rpm
motor1.update();
motor1.setPosition(set);
}
if (RPM > 14000){ // aggle limit to max. 14.000 rpm , begrenzt den Ausschlag damit der Zeiger nicht in der Öl Kontroll LED hängen bleibt
motor1.update();
motor1.setPosition(810);
}
}
void Pulse_Event()
{
PeriodBetweenPulses = micros() - LastTimeWeMeasured;
LastTimeWeMeasured = micros();
if(PulseCounter >= AmountOfReadings)
{
PeriodAverage = PeriodSum / AmountOfReadings;
PulseCounter = 1;
PeriodSum = PeriodBetweenPulses;
int RemapedAmountOfReadings = map(PeriodBetweenPulses, 40000, 5000, 1, 10);
RemapedAmountOfReadings = constrain(RemapedAmountOfReadings, 1, 10);
AmountOfReadings = RemapedAmountOfReadings;
}
else
{
PulseCounter++;
PeriodSum = PeriodSum + PeriodBetweenPulses;
}
}
